[WinXP] Administratorrechte auf Knopfdruck

[pegasusHH]

Administratorrechte auf Knopfdruck

Ich lese immer wieder, dass es sinnvoll ist, das Benutzerkonto mit dem man im Internet surft, von den Rechten her zu beschränken.

Einige Proggis aber benötigen z.B. zur Updatefunktion oder Installation Administratorrechte.

Es wäre doch schön, wenn man z.B. per Button sein eigenes Benutzerkonto mit Administratorrechten ausstatten (z.B. wenn man Offline ist) und wieder abschalten kann.

Ich habe keine Lust ein Extrakonto mit Administratorrechten einzurichten, um mich jedesmal abmelden, und bei diesem Konto anmelden zu müssen, wenn ich mein Benutzerkonto mit Adminrechten ausstatten will.

Jemand eine Idee, wie man das umsetzen kann? Mein Betriebssystem XP Home.

 

[Brummelchen]

"Run as" bzw "Ausführen als..."

 

[Razorblade]

Für die Batchfreaks hab ich ne cmd gefunden:

@echo off
REM ********************************************************************
REM  This batch file starts a command shell under the current user account,
REM  after temporarily adding that user to the local Administrators group.
REM  Any program launched from that command shell will also run with
REM  administrative privileges.
REM
REM  You will be prompted for two passwords in two separate command shells:
REM  first, for the password of the local administrator account, and
REM  second for the password of the account under which you are logged on.
REM  (The reason for this is that you are creating a new logon session in
REM  which the user will be a member of the Administrators group.)
REM
REM  CUSTOMIZATION:
REM  The following values may be changed in order to customize this script:
REM
REM  * _Prog_  : the program to run
REM
REM  * _Admin_ : the name of the administrative account that can make changes
REM              to local groups (usu. "Administrator" unless you renamed the
REM              local administrator account).  The first password prompt
REM              will be for this account.
REM
REM  * _Group_ : the local group to temporarily add the user to (e.g.,
REM              "Administrators").
REM
REM  * _User_  : the account under which to run the new program.  The second
REM              password prompt will be for this account.  Leave it as
REM              %USERDOMAIN%\%USERNAME% in order to elevate the current user.
REM ********************************************************************

setlocal
set _Admin_=%COMPUTERNAME%\Administrator
set _Group_=Administratoren
set _Prog_="cmd.exe /k Title *** %* as Admin *** && cd c:\ && color 4F"
set _User_=%USERDOMAIN%\%USERNAME%

if "%1"=="" (
	runas /u:%_Admin_% "%~s0 %_User_%"
	if ERRORLEVEL 1 echo. && pause
) else (
	echo Adding user %* to group %_Group_%...
	net localgroup %_Group_% "%*" /ADD
	if ERRORLEVEL 1 echo. && pause
	echo.
	echo Starting program in new logon session...
	runas /u:"%*" %_Prog_%
	if ERRORLEVEL 1 echo. && pause
	echo.
	echo Removing user %* from group %_Group_%...
	net localgroup %_Group_% "%*" /DELETE
	if ERRORLEVEL 1 echo. && pause
)
endlocal

So long
RB

 

[pegasusHH]

ääh - kann mir das jemand mal genauer erklären?

Muss ich bei der Batch die Begriffe durch die eigendlichen Namen, wie "Computername" und "Username" ersetzen? - Was ich dann nicht verstehe ist der Begriff" Userdomain".

Heißt das, wenn ich mein Konto mit eingeschränkten Rechten versehe und mich anmelde, dass ich durch den Klick auf die Batch dann Adminrechte habe?

Wenn ja - wie funzt dass dann umgekehrt, wenn ich das Konto wieder einschränken will?

Zur Info: Ich benutze kein Passwort zur Anmeldung (ist Quatsch auf einem nur privat genutzten PC.)

 

[Razorblade]

Sorry!

Du nimmst einfach den Code und fügst Ihn in eine Textdatei ein.
Danach benennst du die Datei in .cmd um. (Stapelverarbeitungsdatei von Windows)

Das einzige was du (möglicherweise) ändern musst ist die Zeile:

set _Admin_=%COMPUTERNAME%\Administrator

Hier änderst du den "Administrator" auf den Namen deines Administratorkontos. (Wird aber nicht nötig sein, es sei denn, du hast den Administrator umbenannt oder hast ein anderssprachiges Windows oder du willst mit einem mit Administratorrechten ausgestattetem benutzerkonto einloggen)

Danach doppelklickst du die Datei und du bekommst ein CMD Fenster, welches dir ermöglicht temporär mit Administratorrechten zu Arbeiten.

Alles was in Prozentzeichen steht muss / darf nicht geändert werden, da das Systemvariablen sind, welche von der Datei automatisch an deinen Rechner angepasst werden.


MfG
RB

 

[pegasusHH]

Habe ich jetzt kapiert- Danke.

Werde ich in den nächsten Tagen mal testen.